Any Browser Campaign

„Ziegenweide“ für den HP-41CX
English version

Die Bilder kommen später !

Gestellt sei folgende Aufgabe : Es gibt eine kreisrunde Weide mit der Fläche AW. An deren Rand ist eine Ziege angeleint. Wie lang darf die Leine höchstens sein, so daß die Ziege höchstens die Hälfte (oder einen beliebigen anderen Prozentsatz p) der Fläche abweiden kann ?

Die Aufgabenstellung wird folgendermaßen gelöst :

AZ setzt sich zusammen aus A1 + A2 (Bild 2).

Die Kreissegmentfläche A1 kann berechnet werden nach :


A1 = r12
2
æ
è
p2a
180°
- sin2a ö
ø
(Bild 3)

Entsprechend wird A2 berechnet :


A2 = r22
2
æ
è
pb
90°
- sin2b ö
ø

Die Größen r2 und b werden nach Bild 4 so berechnet :


y
= r1 ·cosa
x
= r1 ·cosg = r1 ·cos(90° - a)
z
= r1 - y
r2
=   ______
Öx2 + z2
 
cosb
= z
r2
Þ b = arccos z
r2

(Anmerkung: Gleichungen übersetzt von TEX mittels TTH, version 2.70.)

Die weitere Berechnung erfolgt nun so : r1 ist vorgegeben (Radius der Weide), a (nicht 2a !) wird vom Benutzer als Startwert vorgegeben. Der HP-41CX errechnet jetzt A1, A2 und AW und prüft, ob

Ist die vorgegebene Größe von A1 + A2 über- oder unterschritten, so wird a um eine Zehnerpotenz kleiner erhöht oder erniedrigt. So wird der vorgegebene Flächeninhalt immer weiter angenähert, bis die gewünschte Genauigkeit erreicht ist.

Das Programm läßt die Größe von A1 + A2 (= AZ) zwischen 0% < p < 100% zu.

Programmablauf :

Nach Programmstart muß zunächst R1 (Radius der Weide) eingegeben werden. Danach wird der Benutzer aufgefordert, die gewünschte Größe der Fläche, die die Ziege abweiden darf, in Prozent der Weidefläche AW einzugeben. Nun mu&stlig; ein Startwert für a eingegeben werden (ein vernünftiger Startwert bei 50% Größe ist 60°). Je besser der Startwinkel mit dem tatsächlichen Winkel für a übereinstimmt, desto schneller konvergiert der Wert für a. Danach muß: noch die Genauigkeit (Anzahl der Nachkommastellen) eingegeben werden.

Jetzt berechnet der HP-41CX eine erste Näherung für r2, d.h. für die Leinenlänge der Ziege. Dieser bleibt solange in der Anzeige, bis der nächste Näherungswert gefunden ist. Ist der Wert für r2 mit der vom Benutzer vorgegebenen Genauigleit erreicht, so ertönt der BEEP. Nach Löschen der Anzeige mit der Taste "<-" erscheint der Wert für a in der Anzeige (X-Register). Im Y-Register liegt der Wert von b.

Sinkt die Batteriespannung während des Programmlaufs zu sehr ab, so schaltet sich der HP-41CX ab. Nach Wiedereinschalten erscheint BATTERIE in der Anzeige, um auf das Problem hinzuweisen. Der Progammlauf kann nicht fortgesetzt werden.

Registerbelegung : (Habe ich von diesem Programm ausnahmsweise noch ! :-) )

R00 : Anzahl der Stellen (Genauigkeit)
R01 : r1
R02 : r2
R03 : a
R04 : b
R05 : x
R06 : y
R07 : z
R08 : AW
R09 : A1
R10 : Inkrement / Dekrement von a
R11 : Größe von AZ = A1 + A2 in Prozent der Größe von AW

Programmlisting :

001 LBL "ZIEGE"
001  ,011
003  CLRGX
004  CF 00
005  CF 01
006  CLST
007 LBL 00
008  CF 22
009  "R1 ="
010  PROMPT
011  FC? 22
012  GTO 00
013  X<=0?
014  GTO 00
015  STO 01
016 LBL 05
017  CF 22
018  "%-GROESSE ?"
019  PROMPT
020  FC? 22
021  GTO 05
022  X<=0?
023  GTO 05
024   E2
025  /
026  STO 11
027 LBL 08
028   E1
029  "START-W ="         (Anstatt des "W" habe ich das Winkelzeichen (hexadezimal 0D) eingesetzt)
030  PROMPT
031  ABS
032  STO 03
033 LBL 01
034  CF 22
035  "ANZ. STELLEN?"
036  PROMPT
037  FC? 22
038  GTO 01
039   E3
040  /
041  STO 00
042 LBL 15
043  FC? 49
044  GTO 07
045  "BATTERIE"
046  SF 11
047  OFF
048  AVIEW
049  STOP
050 LBL 07
051  RCL 01
052  RCL 03
053  COS
054  *
055  STO 06
056  RCL 01
057  90
058  RCL 03
059  -
060  COS
061  *
062  STO 05
063  RCL 01
064  RCL 06
065  -
066  STO 07
067  X^2
068  RCL 05
069  X^2
070  +
071  SQRT
072  STO 02
073  RCL 07
074  X<>Y
075  /
076  ACOS
077  STO 04
078  PI
079  RCL 01
080  X^2
081  *
082  STO 08
083  LASTX
084  PI
085  RCL 03
086  *
087  90
088  /
089  RCL 03
090  XEQ 02
091  STO 09
092  RCL 02
093  X^2
094  PI
095  RCL 04
096  *
097  90
098  /
099  RCL 04
100  XEQ 02
101  RCL 09
102  +
103  FIX IND 00
104  RND
105  RCL 08
106  RCL 11
107  *
108  RND
109  X=Y?
110  GTO 03
111  X>Y?
112  GTO 04
113  FS? 01
114  GTO 09
115  RCL 03
116  STO 10
117  2
118  ST/ 03
119  GTO 10
120 LBL 09
121  XEQ 13
122  -
123  STO 03
124 LBL 10
125  SF 00
126  GTO 15
127 LBL 04
128  FS? 00
129  GTO 11
130  RCL 03
131  STO 10
132  2
133  ST* 03
134  GTO 12
135 LBL 11
136  XEQ 13
137  +
138  STO 03
139 LBL 12
140  SF 01
141  GTO 15
142 LBL 13
143  RCL 03
144  RCL 10
145  -
146  ABS
147  2
148  /
149  RCL 03
150  STO 10
151  X<>Y
152  RTN
153 LBL 02
154  2
155  *
156  SIN
157  -
158  *
159  2
160  /
161  RTN
162 LBL 03
163  TONE 7
164  RCL 00
165  ISG X
166  ""            (Leeranweisung)
167  CLA
168  FIX 0
169  SF 28
170  ARCL X
171  " NAEHERUNG:"
172  AVIEW
173  PSE
174  CF 28
175  FIX IND 00
176  "R2 = "
177  ARCL 02
178  AVIEW
179  ISG 00
180  GTO 15
181  BEEP
182  RCL 04
183  RCL 03
184  ,011
185  CLRGX
186  CLA
187  CF 00
188  CF 01
189  FIX 4
190  R^
191  CLX
192  RDN
193  CLX
194  STO L
195  RDN
196  END


Zurück zu Ausgewählte (Spiel-)Programme für den HP-41CX

Zurück zu Naturwissenschaften und mathematische Spielereien

Zurück zur Startseite

Kai Schröder, 30.5.2001